Супертриод!

Кружка · October 19, 2024

Захотелось вспомнить такой вариант включения ламп, как супер-триод. Комбинация правой лампы с подходящей управляющей позволяет получить линейные ВАХ при низком внутреннем каскада. Лампы с подобными характеристиками в «одном флаконе» являются весьма востребованными на рынке (со всеми сопутствующими). Тут же наоборот, можно подобрать из кандидатов нашедших слабое распространения в сфере аудио и с хорошими перспективами по результату. Как минимум теоретически.

Кружка · October 19, 2024

Вопрос поднимался и на старом АП, но так и заглох. Несколько сохранившихся картинок с 811 в таком включении.

6%D0%A45%D0%BF%2B%D0%93811.djvu 6%D0%A43%D0%9F%2B%D0%93811.djvu 6%D0%9F44%2B%D0%93811.djvu 6%D0%9F43%D0%9F%2B%D0%93811.djvu 6%D0%9F41%D0%9F%2B%D0%93811.djvu 6%D0%9F31%2B%D0%93811.djvu

Сергей-1968 · April 13

Здравствуйте Все. Тема не популярная, но Г811 не отпускает. Предположим: 6П31С+Г811, нарисовал схемку половина РР, на ВАХ ориентировался на 6П31С Pmax 14Вт, ток примерно 20mA. Прогнал через “МС” в принципе ничего криминального, единственное модель Г811 со старым компом приказала долго жить, по этому ГУ50 по “коэффициенту похожести” все сетки на катод 6П31С. “MC” показывает суммарный ток через обе лампы, собственно вопрос: есть ли какие варианты посмотреть ток на каждой лампе отдельно? Или “MC” не умеет это делать.

alss · April 13

1 час назад, Сергей-1968 сказал:

“MC” показывает суммарный ток через обе лампы, собственно вопрос: есть ли какие варианты посмотреть ток на каждой лампе отдельно?

Поставьте в анод или катод каждой лампы по резистору 0,1-0,001 Ом и задайте график тока через эти резисторы.

SV811-3 и SV811-10?

*-----------------------------------------------------------------------
* Filename:        SV811-3.inc V2 16/6/97
* Simulator:        PSpice
* Device type:        Power triode
* Device model:        Svetlana SV811-3
*
* Author:        Duncan Munro
* Date:            14/6/97
* Copyright:        (C)1997-2000 Duncan Amplification
*
* The following parameters are not modelled:
*
*   (1) Filament: A "cathode" connection is made which
*       should be connected to a potential which is the
*    average of the two filament terminals.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A Anode
*        G Grid
*        K Cathode
*
*-----------------------------------------------------------------------

.SUBCKT SV811-3 A G K
*
* Calculate contribution to cathode current
*
Eat    at    0    VALUE={0.636*ATAN(V(A,K)/30)}
Eme    me    0    VALUE={PWR(LIMIT{V(A,K),0,10000},1.5)/4500}
Emu    mu    0    VALUE={V(G,K)}
Egs    gs    0    VALUE={LIMIT{V(A,K)+V(mu)*3.4,0,1E6}}
Egs2    gs2    0    VALUE={PWRS(V(gs),1.5)*25E-6}
Ecath      cc        0     VALUE={LIMIT{V(gs2),0,V(me)}}
*
* Calculate anode current
*
Ga         A         K         VALUE={V(cc)}
*
* Calculate grid current
*
Gg    G    K    VALUE={PWR(LIMIT{V(G,K)+1,0,1E6},1.5)*(2-V(at))*30E-6}
*
* Capacitances
*
Cgk    G    K    7p
Cga    A    G    8p

.ENDS

*-----------------------------------------------------------------------
* Filename:        SV811-10.inc V2 16/6/97
* Simulator:        PSpice
* Device type:        Power triode
* Device model:        Svetlana SV811-10
*
* Author:        Duncan Munro
* Date:            14/6/97
* Copyright:        (C)1997-2000 Duncan Amplification
*
* The following parameters are not modelled:
*
*   (1) Filament: A "cathode" connection is made which
*       should be connected to a potential which is the
*    average of the two filament terminals.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A Anode
*        G Grid
*        K Cathode
*
*-----------------------------------------------------------------------

.SUBCKT SV811-10 A G K
*
* Calculate contribution to cathode current
*
Eat    at    0    VALUE={0.636*ATAN(V(A,K)/30)}
Eme    me    0    VALUE={PWR(LIMIT{V(A,K),0,10000},1.5)/1800}
Emu    mu    0    VALUE={V(G,K)}
Egs    gs    0    VALUE={LIMIT{V(A,K)+V(mu)*8.7,0,1E6}}
Egs2    gs2    0    VALUE={PWRS(V(gs),1.5)*12E-6}
Ecath      cc        0     VALUE={LIMIT{V(gs2),0,V(me)}}
*
* Calculate anode current
*
Ga         A         K         VALUE={V(cc)}
*
* Calculate grid current
*
Gg    G    K    VALUE={PWR(LIMIT{V(G,K)+1,0,1E6},1.5)*(2-V(at))*73E-6}
*
* Capacitances
*
Cgk    G    K    7p
Cga    A    G    8p

.ENDS

Сергей-1968 · April 13

О, как! Попробую с резисторами в аноде. SV811-3 и SV811-10 эти модели у меня есть,но они уж очень отличаются от Г811. Да и модель для меня написать ... ... , в общем "тёмный лес". Спасибо буду пробовать.